Routines
Prev: 9096 Up: Map Next: 9175
90D6: Start screen
Used by the routine at entry.
start_screen 90D6 CALL $1F85 MODE_1 (pattern generator table at $0000, name table at $1800, color table at $2000)
90D9 LD HL,$0800 Set sprite generator table at $0800 (was $3800)
90DC LD A,$01
90DE CALL $1FB8 INIT_TABLE
90E1 LD HL,$1C00 Set sprite attribute table at $1C00 (was $1B00)
90E4 LD A,$00
90E6 CALL $1FB8 INIT_TABLE
90E9 LD A,$00 Clear all VDP RAM
90EB LD HL,$0000
90EE LD DE,L4000
90F1 CALL $1F82 FILL_VRAM
90F4 CALL $1F7F LOAD_ASCII
90F7 LD HL,stars Stars
90FA CALL upload_patterns Upload 18 star patterns starting with 1
90FD LD HL,buffer Save pattern 33 from VDP to RAM
9100 LD DE,$0108
9103 LD BC,$0008
9106 CALL $1FE2 READ_VRAM
9109 LD HL,buffer Write it back to VDP patern 63
910C LD DE,$01F8
910F LD BC,$0008
9112 RST $38 WRITE_VRAM
9113 LD HL,ship_pattern Write ship pattern to pattern 33
9116 LD DE,$0108
9119 LD BC,$0008
911C RST $38 WRITE_VRAM
911D CALL decompress_patterns Upload patterns to VDP buffer
9120 LD HL,L9380 Gyruss logo names
9123 LD DE,$18A8 Name table address
9126 LD C,$02 2 rows
logo_row 9128 LD B,$06 6 letters
logo_letter 912A LD A,(HL) Get name
912B RST $10 Write VDP byte
912C INC DE Next destination
912D INC HL Next source
912E LD A,(HL) Get name
912F RST $10 Write VDP byte
9130 INC DE Next destination
9131 INC DE Next destination (skip space)
9132 INC HL Next source
9133 DJNZ logo_letter Loop for 6 letters
9135 LD DE,$18C8 Name table address of next row
9138 DEC C Row counter
9139 JR NZ,logo_row Loop for 2 rows
913B CALL init_sprite_data Init sprites
913E LD A,$06 Planet number
9140 CALL display_planet Draw planet 6 (Earth)
9143 CALL upload_sprite_data Upload sprite data
9146 CALL clear_row_7 Clear row 7
9149 LD HL,copyright_msg Copyright message
914C LD DE,$1AE4 Name table address
914F LD BC,$0017 23 bytes
9152 RST $38 WRITE_VRAM
9153 LD DE,$2000 Color table address
9156 LD HL,colors Colors
9159 LD BC,$0013 Update 19 color sets
915C RST $38 WRITE_VRAM
915D LD HL,gyruss_logo Gyruss logo
9160 CALL upload_patterns Upload 20 patterns starting with 128
9163 LD BC,$01E0 Display on, interrupt on
9166 RST $18 WRITE_REGISTER
start_screen_loop 9167 HALT Wait for interrupt
9168 CALL display_stars Display stars
916B CALL upload_sprite_patterns
916E RET NC Return if no carry
916F CALL upload_sprite_patterns
9172 JR C,start_screen_loop Loop until no carry
9174 RET
Prev: 9096 Up: Map Next: 9175